@if "%~1" == "" (
	@echo 入力ファイル名と出力FPSを指定してください
	@echo makeEMMDAt.bat 入力ファイル名 FPS
	@exit /b
)
set inpu_movie=%1
@if "%~2" == "" (
	@echo 出力する fps を指定してください
	@echo makeEMMDAt.bat 入力ファイル名 FPS
	@exit /b
)
set fps=%2
@echo off
@echo 音声抽出開始します
@rem なぜか既存ファイルがあると上書きできない？
@if exist sound_15557Hz.wav (
	del sound_15557Hz.wav
)
@rem CPUクロックから H_BLANK周期で計算すると 15557Hz
powershell -ExecutionPolicy RemoteSigned .\normalize.ps1 %inpu_movie% sound_15557Hz.wav 15557
@echo 映像コマ抽出開始します
@time /T
@if exist output_png (
	@echo 既存の映像コマディレクトリを削除します
	@rd /S output_png
)
@md output_png
ffmpeg -i %inpu_movie% -r %fps% -vcodec png -start_number 0 output_png\%%06d.png
@echo ファイルリストを作成します
@time /T
@if exist m7r (
	@echo 既存のキャラグラディレクトリを削除します
	@rd /S m7r
)
@md m7r
@type nul > FILELIST.lst
for %%A in (output_png\*.png) do (
	echo %%A>> FILELIST.lst
)
@echo 抽出したコマ画像をMZ-700キャラグラに変換します(気長に待て)
@time /T
MZ700GraphicConverter.exe -EU -o m7r -c pmm -OD m7r -F FILELIST.lst
@echo MZ-700キャラグラ画像とwaveデータを結合して EMM.ROM ファイルを作成します
@time /T
m7rToEMMROM.exe -w sound_15557Hz.wav -fps P%fps% -m7r m7r
@echo 出力した EMM.ROM をEmuZ-700と同じフォルダに配置し、EmuZ-700を起動し、
@echo EMMplayer.mzt をモニタからロードしてください。
